;;=====================================================
;; Limmax.LSP (03-07-02) John F. Uhden, Cadlantic
;; Function to permit changing the value of "LIMMAX" in a Paper
;; Space layout whose Paper, Margins, or Shadow are turned ON.
;; An example of using Visual Lisp with ActiveX, R15+
;; Dedicated to Jim Dean
;;
(defun limmax (value / Display Margins Paper Shadow)
  (if (/= (getvar "ctab") "Model")
    (progn
      (setq Display (vla-get-Display (vla-get-Preferences (vlax-get-acad-object)))
            Margins (vlax-get Display "LayoutDisplayMargins")
            Paper   (vlaX-get Display "LayoutDisplayPaper")
            Shadow  (vlaX-get Display "LayoutDisplayPaperShadow")
      )
      (vlax-put Display "LayoutDisplayMargins" 0)
      (vlax-put Display "LayoutDisplayPaper" 0)
      (vlax-put Display "LayoutDisplayPaperShadow" 0)
      (redraw)
    )
  )
  (and
    (listp value)
    (not (atom (cdr value)))
    (vl-every 'numberp value)
    (vl-position (length value) '(2 3))
    (setvar "limmax" value)
  )
  (if Display
    (progn
      (vlax-put Display "LayoutDisplayMargins" Margins)
      (vlax-put Display "LayoutDisplayPaper" Paper)
      (vlax-put Display "LayoutDisplayPaperShadow" Shadow)
      (redraw)
    )
  )
  (getvar "limmax")
)