;; For Jim Fisher (01-18-02)
(and
   (setq layer (tblobjname "layer" "0"))
   (setq layer (vlax-ename->vla-object layer))
   (setq xdict (vla-getextensiondictionary layer))
   (setq xdict (vlax-vla-object->ename xdict))
   (if (setq dict (dictsearch xdict "My Extension Dictionary"))
      (setq dict (cdr (assoc -1 dict)))
      (setq dict (list '(0 . "DICTIONARY") '(100 . "AcDbDictionary"))
            dict (entmakex dict)
            dict (dictadd xdict "My Extension Dictionary" dict)
      )
   )
)
;; VanillaLisp version (01-18-02)
(if
  (and
    (setq layer (tblobjname "layer" "1"))
    (setq xdict nil ent (entget layer))
    (or
      (setq xdict (cdr (assoc 360 (member '(102 . "{ACAD_XDICTIONARY") ent))))
      (and
        (setq xdict (entmakex (list '(0 . "DICTIONARY")(cons 330 layer)'(100 . "AcDbDictionary"))))
        (setq head (reverse (member (assoc 5 ent)(reverse ent))))
        (setq tail (cdr (member (assoc 5 ent) ent)))
        (entmod (append head (list '(102 . "{ACAD_XDICTIONARY")(cons 360 xdict)'(102 . "}")) tail))
      )
    )
  )
  xdict
)